Fehlersuche beim Lernpaket Mikrocontroller

 

 

 

 

 

Bei dem Vorhaben, mein MC-Eprom-Programmiergerät aus dem Jahr 1984 (CD4094-Kette an LPT1, Pascal/Delphi) ins neue Jahrtausend zu führen, kam mir Ihr LehrPaket-msr-USB wegen des kleineren Aufwandes gegenüber Pollin-Spiel1 (meiner altern. Entwicklungsplattform) entgegen. Die intensive Beschäftigung mit "init.asm" (gleich wie im LP Mikrocontroller) führte zu zwei Programm-Modifikationen, die ich Ihnen vorstellen möchte: Veränderung der Kalibrierung des RC-Oszillators: konvergiert jetzt viel schneller - und die Portierung der Atmel-AN AVR305 auf init.asm (klein, sparsam).

;
;Kalibrierung des RC-Oszillators mit 9,6 MHz, DIV8 = 1,2 MHz über den OSCCAL-Wert
;
;PC sendet $00, Tiny misst 9 H-Pegel mit 5 cy-Loops: nom. 25 Loops x 9 Bit = 225 Loops
;vergleich mit nom. Wert: 9 x 104,1666us = 0,9375ms = 225 Loops: 9 x 25 x 5 x 0,8333us
;mod. 2015 07 14 khs

Cal: 			;RC-Oszillator gegen RxD, 9 Bit-Zeiten, 9600 Bd abgleichen
      in     B,osccal	;OSCCAL -> B für Regelung (successive Approximation)
      mov    EEadr,B    ;OSCCAL in EEadr zwischenspeichern, f. korrekte Anzeige unten
      subi   B,$0A	;B=OSCCAL-10, initialer Versuchswert, ca. -11%!
      ldi    D,$2D	;max.  Abweichung: 45 = $2D, Vorgabewert
      ldi    Cnt2,$0F	;Loop-Cntr, Initialwert 15, für Not-Abbruch!
C1:
      out    osccal,B	;OSCCAL aus B setzen, akt. Versuchswert f. Messung
      inc    D		;(Max+1)-Wert, da Tiny nichtlinear bzw. Messfehler auftreten
      rcall  RdRXD     	;RxD: H->L; Dauer messen: 9 Bits a 25*5cy = 225 cy 
      subi   A,$E1    	;225 = $E1: Regelschwelle
      neg    A		;kleinerer OSCCAL-Wert ergibt negative Abweichung 
      cp     D,A	;Vergleiche Abweichung A gegen (Max+1)-Wert in D
      brsh   C3		;A =< D;  A > D: Schleifen-Ende wenn Abweichung ansteigt
C2:   
      ldi    Cnt2,1	;1 -> 0: Schleifen-Ende; 224->> 225 <<-226!
      neg    A      	;- x - = +! (minus mal minux gibt plus)
      dec    D   	;für korrekten Vergleich mit D (Max+1) - 1   
      cp     A,D	;Regel-Abweichung vergleichen     
      brsh   C4		;akt. OSCCAL ist schlechter (Abw.n+1 >= Abw.n)
C3:      
      mov    C,B	;akt. OSCCAL in C sichern
C4:      
      mov    D,A	;Abweichung in D sichern
      out    osccal,EEadr ;OSCCAL setzen für korrekte Anzeige/Ausgabe
      rcall  WrCOM	;Abweichung aus A ser. ausgeben
      mov    A,B	;akt. OSCCAL -> A
      rcall  WrCOM	;akt. OSCCAL ser. ausgeben
      mov    A,D	;Neuen OSCCAL aus Abweichung bestimmen:
      lsr    A		;div 2
      lsr    A		;div 2: div 4 (ohne Rest)
      brne   C5		;wenn A > 0, sonst...
      inc    A		;A=0: 0 konvertiert nicht, daher +1!
C5:   add    B,A	;Verbesserung des Versuchswertes OSCCAL     
      dec    Cnt2	;15, 14, ... 0 oder Abbruch
      brne   C1		;Schleifen-Ende bei Cnt2=0
;
      mov    A,C	;Bester OSCCAL-Wert der Regel-Schleifen
      out    osccal,A	;OSCCAL setzen
      ldi    EEadr,$3F	;EE-Adr für Speichern des OSCCAL-Wertes
      rcall  WrEE	;EE($3F) setzen (A bleibt erhalten)
      rcall  WrCOM	;A ser. ausgeben: Bester OSCCAL-Wert
      ret
;
RdRXD:			;ImpulsDauer messen: RxD=1 bis RxD=0: _|........|_._
      sbis  PINB,RXD 	;RxD testen; $00, 9,6 kBaud, 25 Loops/Bit, 9 Bits = 225 cy
      rjmp  RdRXD	;RxD=0, auf Startbit RxD=1 warten
      ldi   A,0  	;RxD=1, Zaehler-Anfangswert=0
RXD1: inc   A    	;A=A+1, H->L  auszaehlen  ;1cy
      nop             	;dt		;1cy   (25,50,75,100,125,150,175,200,225)
      sbic  PINB,RXD  	;RxD testen	;1cy (w/o skip)
      rjmp  RXD1      	;RxD=1		;2cy  ;  total  5 Takte
      ret		;RxD=0,   all done
;
;---
;

;
;  Software-UART von AVR305 auf LPmsrUSB init.asm portiert, 2015 04 28 khs
;---
; RS232-Invertierung: 	Stoppbit (Ruhe): -5V := TTL=0, log. Wert=1 
; spielt!		Startbit: 	 +5V :=	TTL=1, log. Wert=0
;
;  			;Byte ser. Empfangen, st,8b,1sp
RdCOM:  sbis  pinb,RXD		;2cy,	Test RxD wg Stt-Bit
        rjmp  RdCOM		;RxD=-5V (RS232-Invertierung)
;				;RxD=+5V Stt-Bit: +5V, TTL=1,log 0
        ldi   Cntr,9		;1cy,	st,8b,1sp
        ldi   Delay,20		;1cy	;125+62=187
        rcall WDL2		;3cy	;113+12+20*3-1+4=185; ~1,5 Bit
; 
RL:     rcall WDL1		;3cy	;125-12=113: 36*3-1+6=113 ;
	nop			;1cy	;timing
        sec			;1cy
        sbic  pinb,RXD		;___---
        clc			;1cy+1cy
        dec   Cntr		;1cy
        breq  WEX		;1cy,	go home (bei WrCOM)
	ror   A			;1cy
	rjmp  RL		;2cy,	LOOP
;	
;
; RS232-Invertierung: 	Stoppbit (Ruhe): -5V := TTL=0, log. Wert=1 
; spielt!		Startbit: 	 +5V :=	TTL=1, log. Wert=0
;
WrCOM:  ldi   Cntr,10		;1cy, Byte ser. Senden, st,8b,1 1/2sp
        com   A 	  	;1cy,	A=/A, C=1, wg RS232-Inv. Stt/Stp-Bit, s.u.
WxL:    brcs  Wx1		;2/1cy,	teste C	
        cbi   PORTB,TXD		;2cy---	C=0: TxD=0 (RS232-Inv.: Stp-Bit=-5V (1))
	rjmp  WxC		;2cy
;					system. Flanken-Jitter (0,8us/104us)
Wx1:    sbi   portb,TXD		;2cy---	C=1: TxD=1 (RS232-Inv.: Stt-Bit=+5V (0))
	nop			;1cy,	wait
	
WxC:    rcall WDL1		;3cy	;125-12=113: 36*3-1+6=113 
        lsr   A			;1cy,	A,b0->C, nächstes Bit zur Ausgabe
        dec   Cntr		;1cy,	Zähler verkleinern
        brne  WxL		;2/1cy_	LOOP
;	
WDL1:   ldi   Delay,36  	;1cy,	Delay for 9600 Bd Bit soll: (104,16 us := 125 cy)
        nop			;1cy    ;timing,  Time-DL1: 36*3-1+6=113           			
WDL2:   dec   Delay		;1cy
        brne  WDL2		;2/1cy: 3cy/Loop  Time-DL2: n*3cy-1cy+4cy	
WEX:    ret			;4cy
;
;----
;